[annikk.exe]

Hello,

Thought I'd share a batch I wrote today for work.

My boss wanted a folder that opens on the far right hand side of his screen (always in this position). The problem with Windows 7 is that if you move a Windows Explorer window into some obscure position, the position is saved and subsequent Explorer windows are the same dimensions and in the same position.

So I had to find a way to open the window always in this one precise place, but without affecting any other Windows Explorer windows that were opened afterward.


Here is my solution.
Spoiler (Click to View)

Code

REM Batch to open folder with window at specific screen position
REM WITHOUT affecting the positions of subsequent windows

@echo off
cls

REM First lets set out our desired window's properties:


    set folderlocation=C:\omgfolder

    set wintop=0
    set winbottom=1080

    set winleft=3640
    set winright=3940



REM Some other inits..

    set WIN_SIZE_KEY="HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags\AllFolders\Shell"
    set NAV_PANE_KEY="HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer"

REM Record the current settings so we can restore them after

    REM Window Size
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %WIN_SIZE_KEY% /v WinPos1920x1080x96^(2^).top`) do ( set oldtop=%%A )
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %WIN_SIZE_KEY% /v WinPos1920x1080x96^(2^).bottom`) do ( set oldbottom=%%A )
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %WIN_SIZE_KEY% /v WinPos1920x1080x96^(2^).left`) do ( set oldleft=%%A )
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %WIN_SIZE_KEY% /v WinPos1920x1080x96^(2^).right`) do ( set oldright=%%A )

    REM Detail Pane
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %NAV_PANE_KEY% /v PreviewPaneSizer`) do ( set olddetailpane=%%A )    

    REM Nav Pane
    for /F "usebackq skip=2 tokens=3" %%A IN (`reg query %NAV_PANE_KEY% /v PageSpaceControlSizer`) do ( set oldnavpane=%%A )    


    echo oldtop is %oldtop%
    echo oldbottom is %oldbottom%
    echo oldleft is %oldleft%
    echo oldright is %oldright%
    echo olddetailpane is %olddetailpane%
    echo old nav pane is %oldnavpane%




REM Now edit the registry to set up the desired screen position

    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).top /t REG_DWORD /f /d %wintop%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).bottom /t REG_DWORD /f /d %winbottom%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).left /t REG_DWORD /f /d %winleft%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).right /t REG_DWORD /f /d %winright%

REM Next, edit the registry to remove the Details and Nav Panes

    reg add %NAV_PANE_KEY% /v PreviewPaneSizer /t REG_BINARY /f /d 4500000000000000000000000c020000
    reg add %NAV_PANE_KEY% /v PageSpaceControlSizer /t REG_BINARY /f /d 9e000000000000000000000023030000


REM Now everything is ready, lets create our window!

    REM very short delay..

    %SystemRoot%\explorer.exe "%folderlocation%"
    ping 127.0.0.1 -n 2 > nul

REM If all went well, we should now have a window opened in a specific location.
REM Now we need to restore the values so subsequent windows won't spawn in this configuration

    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).top /t REG_DWORD /f /d %oldtop%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).bottom /t REG_DWORD /f /d %oldbottom%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).left /t REG_DWORD /f /d %oldleft%
    reg add %WIN_SIZE_KEY% /v WinPos1920x1080x96(2).right /t REG_DWORD /f /d %oldright%

    reg add %NAV_PANE_KEY% /v PreviewPaneSizer /t REG_BINARY /f /d %olddetailpane%
    reg add %NAV_PANE_KEY% /v PageSpaceControlSizer /t REG_BINARY /f /d %oldnavpane%


REM Done restoring, and done in general.  We can exit..

Notes:
You'll need to change the target folder that is to be opened to one of your own choosing. (The folderlocation variable..)

You'll also need to specify the location you want the window to open in. (The wintop, winbottom, winleft, and winright variables..)

This version is set up 1920x1080 resolution. If your resolution is different, find and replace all occurences of 1920x1080 to whatever your resolution is.


I hope this is useful to someone. :>

[Defcon 12]

Seems legit, well done OP :D Needed it for a few things.

[Johnny Cache]

This OP... is Actually total awesome!

[HACKERMIND]

wow thanks for this it very nice ..... xD

[annikk.exe]

You're welcome. :P

[img]http://static.tvtropes.org/pmwiki/pub/images/MTG-ThreadNecromancer_3198.jpg[/img]