[ɩᴄᴀʀᴜȿ ᴌוᴠᴇѕ™]

Hello all ^-^

PLEASE NOTE THIS CODE ONLY WORKS ON WINDOWS 10

I hope you all enjoy this Prince - Purple Rain tribute.
HERE IS THE OLD CODE - https://hackforums.net/showthread.php?tid=5572917


PLEASE NOTE THIS CODE ONLY WORKS ON WINDOWS 10


PLEASE NOTE THIS CODE ONLY WORKS ON WINDOWS 10

Code

@echo off & setlocal enableDelayedExpansion & color 0D
mode 50,50

set ^"LF=^

^" Above empty line is required - do not remove
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
for /F %%a in ('echo prompt $E^| cmd') do set "ESC=%%a"

<nul set /p "=!esc![?25l"

rem %plot% x y 0-255 CHAR
set plot=for %%# in (1 2) do if %%#==2 ( for /f "tokens=1-4" %%1 in ("^!args^!") do (%\n%
  set "screen=^!screen^!!esc![%%2;%%1H!esc![38;5;%%3m%%~4!esc![0m"%\n%
)) else set args=

rem line x1 y1 x2 y2 color
set line=for %%# in (1 2) do if %%#==2 ( for /f "tokens=1-5" %%1 in ("^!args^!") do (%\n%
    if "%%~5" equ "" ( set "hue=30" ) else ( set "hue=%%~5")%\n%
    set /a "xa=%%~1", "ya=%%~2", "xb=%%~3", "yb=%%~4", "dx=%%~3 - %%~1", "dy=%%~4 - %%~2"%\n%
    for /f "tokens=1-2" %%6 in ("^!dx^! ^!dy^!") do (%\n%
        if %%~7 lss 0 ( set /a "dy=-%%~7", "stepy=-1" ) else ( set "stepy=1" )%\n%
        if %%~6 lss 0 ( set /a "dx=-%%~6", "stepx=-1" ) else ( set "stepx=1" )%\n%
        set /a "dx<<=1", "dy<<=1"%\n%
    )%\n%
    for /f "tokens=1-9" %%a in ("^!dx^! ^!dy^! ^!xa^! ^!xb^! ^!ya^! ^!yb^! ^!stepx^! ^!stepy^! ^!hue^!") do (%\n%
        if %%~a gtr %%~b (%\n%
            set /a "fraction=%%~b - (%%~a >> 1)"%\n%
            for /l %%x in (%%~c,%%~g,%%~d) do (%\n%
                for /f "tokens=1" %%6 in ("^!fraction^!") do if %%~6 geq 0 set /a "ya+=%%~h", "fraction-=%%~a"%\n%
                set /a "fraction+=%%~b"%\n%
                for /f "tokens=1" %%6 in ("^!ya^!") do (%\n%
                    ^!plot^! %%x %%~6 %%i l%\n%
                )%\n%
            )%\n%
        ) else (%\n%
            set /a "fraction=%%~a - (%%~b >> 1)"%\n%
            for /l %%y in (%%~e,%%~h,%%~f) do (%\n%
                for /f "tokens=1" %%6 in ("^!fraction^!") do if %%~6 geq 0 set /a "xa+=%%~g", "fraction-=%%~b"%\n%
                set /a "fraction+=%%~a"%\n%
                for /f "tokens=1" %%6 in ("^!xa^!") do (%\n%
                    ^!plot^! %%~6 %%y %%i l%\n%
                )%\n%
            )%\n%
        )%\n%
    )%\n%
)) else set args=

set "drops=10"
for /l %%a in (0,1,%drops%) do (
   set /a "s[%%a]=!random! %% 5 + 2)", "l[%%a]=!random! %%  2 + 1"
   set /a "x[%%a]=!random! %% 50",   "y[%%a]=(!random! %% -5) - 6"
) 2>nul

for /l %%0 in (0,1,1000) do (

    for /l %%a in (0,1,%drops%) do (
  
        set /a "y[%%a]+=s[%%a]", "yl=y[%%a] + l[%%a]"
      
        %line% !x[%%a]! !y[%%a]! !x[%%a]! !yl! 90
      
        if !y[%%a]! geq 50 (
            set /a "y[%%a]=!random! %% -5 - 6"
            set /a "s[%%a]=!random! %% 20 + 4"
            set /a "x[%%a]=!random! %% 50"
            set /a "l[%%a]=!random! %% 2 + 1"
        )
    )
    <nul set /p "=%esc%[2J!screen!" & set "screen="
)
exit

[Hackoo]

Nice and good work !
I tested it on my Windows 10 and it works 5/5

[Phlox]

Very nice work, keep up the good work please!